Trefoil  =  X[a, d, b, e] X[e, b, f, c] X[c, f, d, a]

The definition of the Kauffman Bracket is given by the skein relations 
and

\(The\ first\ rule\ can\ be\ coded\ as\ \(\(follows\)\(:\)\)\)

rule1  =  (X[a_, b_, c_, d_]  :>  
            A δ[a d] δ[b c]  +  
              B δ[a b] δ[c d]);

Let as apply the first rule to the trefoil knot, just as an example:

Trefoil  /.  rule1

Trefoil  /.  rule1  //  Expand

We see that we need a rule that will dispose of unnecessary "intermidiate" points:

rule2  =  (δ[a_ b_] δ[b_ c_]  :>  δ[
              a c]);

(Trefoil  /.  rule1  //  Expand)  //.  rule2

This done, we can code the second rule, (using dd instead of d, to avoid naming conflicts)

rule3  =  {(δ[_])^2  ->  
            dd,  δ[_^2]  ->  dd};

and see what heppens to the trefoil knot:

RawBracket[t_]  :=  
      Simplify[(t /. rule1  //  Expand)  //.  rule2  /.  
          rule3]

RawBracket[Trefoil]

Let's verify the second Reidemeister move:

RawBracket[
        X[b, e, f, a] X[f, e, c, d]] == δ[a d] δ[
          b c]

Thus we see that for the second Reidemeister move to hold, we must have A B==1 and (A^2) + (B^2) + A B d == 0. Solving for B and dd in terms of A we get:

rule4  =  {B  ->   1/A,  dd  ->  -A^2 - 1/A^2}

Time to check the third Reidemeister move :  (It' 
            s guaranteed to hold,  
          but loose nothing by checking again)

Bracket[t_]  :=  Simplify[RawBracket[t]/dd  /.  rule4]

Bracket[X[a, b, g, i] X[g, c, d, h] X[i, h, e, f]]

Bracket[X[b, c, i, h] X[d, e, g, i] X[g, f, a, h]]

The remaining sad point is the behavior of the bracket under the first Reidemeister move:

Simplify[RawBracket[X[c, a, b, c]]  /.  rule4]

This is unfortunate, but not fatal .  It can be fixed by multiplying the bracket by -(A^3) raised to an appropriate multiple of the writhe .  It is common to make the further substiturion A -> (q^(1/4)) and then the resulting invariant is called "the Jones polynomial" .  Let us compute it for the trefoil and its mirror image:

Jones[t_,  w_]  :=  
      Simplify[(Bracket[t] (-A^3)^(-w))  /.  
          A -> q^(1/4)]

Jones[Trefoil,  3]

MirrorTrefoil  =   Trefoil  /.  
        x_X  :>  RotateLeft[x]

Jones[MirrorTrefoil, -3]

Ok, if you insist,

w[K_]  :=  
      Module[
{p, l}, 
l = 
          ReplacePart[
              K /. X[a_, b_, c_, 
                    d_] :> δ[a c] δ[b d], 
              p, {1, 0}] //. {p[a_ b_] :> 
                p[a, b], 
              p[a_, b___, c_] δ[c_ d_] :> 
                p[a, b, c, d]}; 
l = 
          MapThread[
            Rule, {List @@ l, 
              Range[Length[
                  l]]}]; 
(Plus  @@  (K  /.  
                  l))  /.  
          X[a_, b_, c_, d_]  :>  
            If[Abs[p = (a - c) (b - d)] == 1, 
              p, -Sign[p]]
]

Jones[K_]  :=  Jones[K, w[K]]

{Jones[Trefoil], Jones[MirrorTrefoil]}

Now, last but not least,

Expand[(
q*(-A^3)^(-1)*
              RawBracket[X[a, b, c, d]] - 
            q^(-1)*(-A^3)*
              RawBracket[
                X[b, c, d, a]]
)  /.  {A -> 
            q^(1/4),  
          B -> q^(-1/4)}
]